Fewona.Net

Here you can share, ask or request an mIRC scripts

i want to share a mIRC scripts fun game (Roulette table)

Code: Select all

on *:text:!play*:#: { 
  if (!$hget(Roully, $address($nick,2))) { msg $chan $nick you don't have an account, type !new | halt }
  if ($3 !isnum) { msg $chan You can only bet numerical values. | Halt }
  if ($left($3,1) == $chr(45)) { msg $chan You can not use negative numbers $nick | halt }
  if ($3 <= 0) { msg $chan Please use a positive number. | halt }
  if ($3) && ($hget(Roully, $address($nick,2)) < $3) { msg $chan You can not wager that much $nick as you only have $chr(36) $+ $hget(Roully, $address($nick,2)) $+ . | halt }
  if ($2 == Red || $2 == Black || $2 == Odd || $2 == Even || $2 == Row1 || $2 == Row2 || $2 == Row3 || $2 == Column1 || $2 == Column2 || $2 == Column3 || $2 isnum) {
    if ($2 != num || $2 < 27 && $2 >= 0) {
      if (%rltimer != on) {
        set %rltimer on
        msg $chan You now have 60 seconds to place your bets
        timer 1 60 msg $chan Betting is now off
        timer 1 60 unset %rltimer
        timer 1 60 /spin $chan
      }
      msg $chan Your bet has been added to the table!
      write bets.txt $address($nick, 2) $nick $2 $3
      hdec Roully $address($nick, 2) $3
    }
  }
  else { msg $chan That is not a valid bet, try !play red 1000 }
}
alias spin {
  var %num = $rand(0,36)
  msg $1 The Roulette spins and lands on %num
  if (%num == 0) { var %bets = 0 }
  if (%num == 1) { var %bets = 1 red odd row1 column1 }
  if (%num == 2) { var %bets = 2 black even row2 column1 }
  if (%num == 3) { var %bets = 3 red odd row3 column1 }
  if (%num == 4) { var %bets = 4 black even row1 column1 }
  if (%num == 5) { var %bets = 5 red odd row2 column1 }
  if (%num == 6) { var %bets = 6 black even row3 column1 }
  if (%num == 7) { var %bets = 7 red odd row1 column1 }
  if (%num == 8) { var %bets = 8 black even row2 column1 }
  if (%num == 9) { var %bets = 9 red odd row3 column1 }
  if (%num == 10) { var %bets = 10 black even row1 column1 }
  if (%num == 11) { var %bets = 11 black odd row2 column1 }
  if (%num == 12) { var %bets = 12 red even row3 column1 }
  if (%num == 13) { var %bets = 13 black odd row1 column2 }
  if (%num == 14) { var %bets = 14 red even row2 column2 }
  if (%num == 15) { var %bets = 15 black odd row3 column2 }
  if (%num == 16) { var %bets = 16 red even row1 column2 }
  if (%num == 17) { var %bets = 17 black odd row2 column2 }
  if (%num == 18) { var %bets = 18 red even row3 column2 }
  if (%num == 19) { var %bets = 19 red odd row1 column2 }
  if (%num == 20) { var %bets = 20 black even row2 column2 }
  if (%num == 21) { var %bets = 21 red odd row3 column2 }
  if (%num == 22) { var %bets = 22 black even row1 column2 }
  if (%num == 23) { var %bets = 23 red odd row2 column2 }
  if (%num == 24) { var %bets = 24 black even row3 column2 }
  if (%num == 25) { var %bets = 25 red odd row1 column3 }
  if (%num == 26) { var %bets = 26 black even row2 column3 }
  if (%num == 27) { var %bets = 27 red odd row3 column3 }
  if (%num == 28) { var %bets = 28 black even row1 column3 }
  if (%num == 29) { var %bets = 29 black odd row2 column3 }
  if (%num == 30) { var %bets = 30 red even row3 column3 }
  if (%num == 31) { var %bets = 31 black odd row1 column3 }
  if (%num == 32) { var %bets = 32 red even row2 column3 }
  if (%num == 33) { var %bets = 33 black odd row3 column3 }
  if (%num == 34) { var %bets = 34 red even row1 column3 }
  if (%num == 35) { var %bets = 35 black odd row2 column3 }
  if (%num == 36) { var %bets = 36 red even row3 column3 }
  var %count = 1
  while ($read(bets.txt, %count) != $null) {
    var %add = $wildtok($read(bets.txt, %count), *, 1, 32)
    var %nick = $wildtok($read(bets.txt, %count), *, 2, 32)
    var %bet = $wildtok($read(bets.txt, %count), *, 3, 32)
    var %ammount = $wildtok($read(bets.txt, %count), *, 4, 32)
    if (%bet isin %bets) {
      if (%bet == Red || %bet == Black || %bet == Odd || %bet == Even) {
        hinc Roully %add $calc(%ammount * 2)
        msg $1 %nick has won %ammount with their bet on %bet
      }
      if (%bet == Row1 || %bet == Row2 || %bet == Row3 || %bet == Column1 || %bet == Column2 || %bet == Column3) {
        hinc Roully %add $calc(%ammount * 3)
        msg $1 %nick has won $calc(%ammount * 2) with their bet on %bet
      }
      if (%bet == 0 || %bet == 1 || %bet == 2 || %bet == 3 || %bet == 4 || %bet == 5 || %bet == 6 || %bet == 7 || %bet == 8 || %bet == 9 || %bet == 10 || %bet == 11 || %bet == 12 || %bet == 13 || %bet == 14 || %bet == 15 || %bet == 16 || %bet == 17 || %bet == 18 || %bet == 19 || %bet == 20 || %bet == 21 || %bet == 22 || %bet == 23 || %bet == 24 || %bet == 25 || %bet == 26 || %bet == 27 || %bet == 28 || %bet == 29 || %bet == 30 || %bet == 31 || %bet == 32 || %bet == 33 || %bet == 34 || %bet == 35 || %bet == 36) {
        hinc Roully %add $calc(%ammount * 37)
        msg $1 %nick has won $calc(%ammount * 36) with their bet on %bet 
      }
    }
    inc %count
  }
  msg $1 All other bets were lost, better luck next time!
  remove bets.txt
}
on *:text:!new:#:{
  if ($hget(Roully, $address($nick,2)) < 0 || $hget(Roully, $address($nick,2))) { msg $chan $nick You already have an account. | halt }
  if (!$hget(Roully, $address($nick,2)) || $hget(Roully, $address($nick,2)) >= 0) {
    hadd -m Roully $address($nick,2) 100000
    msg $chan A new account has been created. $nick has $chr(36) $+ 100000 to gamble.
  }
}
on *:text:!money*:#:{
  if (!$2) {
    if ($hget(Roully, $address($nick,2)) > 0) { msg $chan $nick has $chr(36) $+ $hget(Roully, $address($nick,2)) dollars. }
    else { msg $chan $nick is broke. | halt }
  }
  else if ($2 == $me) { msg $chan I am rich! Fear me! | halt }
  else if ($2 != $me) {
    if ($hget(Roully, $address($2,2)) > 0) { msg $chan $2 has $chr(36) $+ $hget(Roully, $address($2,2)) dollars. }
    else { msg $chan $2 is broke. | halt }
  }
}
on *:text:!reset*:#: {
  if (!$2) {
    if ($hget(Roully, $address($nick,2)) < 0 || !$hget(Roully, $address($nick,2))) { msg $chan You do not have an account. | halt }
    if ($hget(Roully, $address($nick,2)) || $hget(Roully, $address($nick,2)) >= 0) {
      hadd Roully $address($nick,2) 100000
      msg $chan $nick $+ 's money has been reset to $chr(36) $+ 100000.
    }
  }
}
on *:text:!give*:#: {
  if ($2) {
    if (!$hget(Roully, $address($nick, 2))) { msg $chan You do not have an account. | halt }
    if (!$hget(Roully, $address($2, 2))) { msg $chan This person does not have an account. | halt }
    if ($hget(Roully, $address($nick,2)) > $3) {
      hdec Roully $address($nick,2) $3
      hinc Roully $address($2,2) $3
      msg $chan $nick gave $2 $ $+ $3 $+ .
    }
    else { msg $chan You do not have that much money to give }
  }
}
on *:text:!rlycommands*:#: {
  msg $chan !New, !Reset, !Money/!Money (Nick), !Give (Nick), !Play (Bet) (Ammount)
  msg $chan Bets are Red, Black, Odd, Even, Row1 - Row3, Column1 - Column3, 0 - 36
}

step installation:
Open you mIRC remote (ALT+R)
put the code in remote windows
type /remote on
enjoy

How command and play:
!New
!Money/!Money (Nick)
!Reset
!Give (Nick)
!Play (Bet) (Ammount)
e.g. !Play Red 100000

Bets:
Red, Black, Odd, Even, Row1 - Row3, Column1 - Column3, 0 - 36

warning:
this script maybe will flood your channel room

here mIRC script horoscope zodiac

Code: Select all

;Horoscope script by Ford_Lawnmower irc.Geekshed.net #Script-Help
menu Channel,Status {
  .$iif($group(#Horoscope) == On,$style(1)) Horoscope Trigger
  ..$iif($group(#Horoscope) == On,$style(2)) On: .enable #Horoscope
  ..$iif($group(#Horoscope) == Off,$style(2)) Off: .disable #Horoscope
}
#Horoscope ON
On $*:Text:/^(\+|-|!|@)Horo/Si:#: {
  ;Change line 10 to change the trigger character. Valid characters are @ and !. If you want to use another character you will have to add it to the regex on line 8.
  var %CommandChar !
  var %action $regml(1)
  if (%action isin +-) && ($regex($nick($chan,$nick).pnick,/(!|~|&|@)/)) {
    if (%action == +) {
      if ($istok(%HoroscopeChanList,$+($network,$chan),32)) { .msg $chan $nick $+ , $chan horoscope telah aktif }
      else {
        Set %HoroscopeChanList $addtok(%HoroscopeChanList,$+($network,$chan),32)
        .msg $chan $nick telah mengaktifkan fitur horoscope di $chan .
      }
    }
    else {
      if (!$istok(%HoroscopeChanList,$+($network,$chan),32)) { .msg $chan $nick $+ , $chan tidak mengaktifkan fitur horoscope }
      else {
        Set %HoroscopeChanList $remtok(%HoroscopeChanList,$+($network,$chan),1,32)
        .msg $chan $nick telah mematikan fitur horoscope di $chan .
      }
    }
  }
  elseif (!$timer($+(Horoscope,$network,$nick))) && ($istok(%HoroscopeChanList,$+($network,$chan),32)) {
    .timer $+ $+(Horoscope,$network,$nick) 1 6 noop
    var %method $iif(%action == %CommandChar,.notice $nick,$iif($regex($nick($chan,$nick).pnick,/(!|~|&|@|%)/),.msg $chan,.notice $nick))
    GetHoroscope %method $2-
  }
}
#Horoscope END
alias Horoscope { GetHoroscope echo -a $1- }
alias -l GetHoroscope {
  if ($signcheck($3)) {
    var %sign $v1
    $1-2 05Ok $nick $+ . Please wait05...
    var %sockname $+(Horoscope,$network,$2,$ticks)
    sockopen %sockname uk.astrology.yahoo.com 80
    sockmark %sockname $1-2 $+(/channels/horoscopes_astrology/horoscopes.php?sign=,%sign)
  }
  else { $1-2 05Ketik zodiak kamu setelah !horo, contoh: !horo gemini }
}
On *:sockopen:Horoscope*: {
  if (!$sockerr) {
    sockwrite -nt $sockname GET $gettok($sock($sockname).mark,3,32) HTTP/1.1
    sockwrite -n $sockname Host: $sock($sockname).addr
    sockwrite -n $sockname $crlf
  }
  else { echo -st Socket Error $nopath($script) | sockclose $sockname | return }
}
On *:sockread:Horoscope*: {
  if ($sockerr) { echo -st Socket Error $nopath($script) | sockclose $sockname | return }
  else {
    var %Horoscope | sockread %Horoscope
    if (Location:* iswm %horoscope) {
      tokenize 32 $sock($sockname).mark
      sockclose $sockname
      var %sockname $+(Horoscope,$network,$2,$ticks),
      sockopen %sockname uk.astrology.yahoo.com 80
      sockmark %sockname $1-2 $+(/horoscopes/,$gettok(%horoscope,4,47),/)
    }
    elseif ($regex(%Horoscope,<div class="astro-tab-body">(.*?)<\/div>)) {
      put $gettok($sock($sockname).mark,1-2,32) $+($regml(1),.)
      sockclose $sockname
      return
    }
  }
}
alias -l Put {
  if (!$regex($1,/(\.|^)(msg|notice|echo)$/Si)) || (!$3) { echo -st **Put error** Syntax /Put msg #channel text - or - /Put notice nickname text  | return }
  var %tokens $0, %Tstart 3, %Dtimer 1500
  if ($timer($+(Put,$2,$network)).secs) { %Dtimer = $calc($v1 * 1000) } 
  while ($len($($+($,%Tstart,-,%tokens),2)) > 350) {
    dec %tokens
    if ($len($($+($,%Tstart,-,%tokens),2)) <= 350) {
      .timer -m 1 %Dtimer $1-2 05H14oroscope0504 $($+($,%Tstart,-,%tokens),2))
      inc %Dtimer 1500
      %Tstart = $calc(%tokens + 1)
      %tokens = $0
    }
  }
  .timer -m 1 %Dtimer $1-2 05H14oroscope0504 $($+($,%Tstart,-,%tokens),2))
  .timer $+ $+(Put,$2,$network) -m 1 $calc(%Dtimer + 1500) noop
}
alias -l SignCheck {
  var %s $lower($left($strip($1),3))
  if ($istok(ari tau gem can leo vir lib sco sag cap aqu pis,%s,32)) return %s
  else { return 0 }
}


Put in your mIRC remote window..

Very nice, thanks

this is new wikipedia script (international en version)

Code: Select all

;Wikipedia Script by Ford_Lawnmower -- irc.mindforge.org #USA-Chat
On $*:Text:/(^[!@])wikien +/Si:#: {
  if ($regml(1) == @) && ($nick isop $chan) {
    var %sockname $+(wiki,$network,$chan)
    sockclose %sockname
    sockopen %sockname en.wikipedia.org 80
    sockmark %sockname .msg $chan $fixurl($formaturl($2-))
  }
  else {
    if (!$timer(wiki $+ $nick)) {
      .timer $+ $+(wiki,$nick) 1 10 noop
      var %sockname $+(wiki,$network,$chan)
      sockclose %sockname
      sockopen %sockname en.wikipedia.org 80
      sockmark %sockname .notice $nick $fixurl($formaturl($2-))
    } 
  }
}
On *:Sockopen:wiki*: {
  sockwrite -nt $sockname GET $+(/w/index.php?title=,$gettok($sock($sockname).mark,3,32),&redirect=yes) HTTP/1.1
  sockwrite -n $sockname User-Agent: Opera 9.6
  sockwrite -n $sockname Host: en.wikipedia.org $+ $str($crlf,2)
}
on *:sockread:wiki*: {
  if ($sockerr > 0) { echo -at >Sock Error< Wikipedia | sockclose $sockname }
  else {
    sockread -n &wiki
    if $bvar(&wiki, 0) {
      if ($bintween(&wiki,<b>,</p>,1)) {
        var %msgs $gettok($sock($sockname).mark,1,32), %targets $gettok($sock($sockname).mark,2,32)
        bset -t &result 1 $bvar($bintween(&wiki,<p>,</p>,1), 1, $bvar(&wiki, 0)).text
        if (may refer to: isin $bvar($binstrip(&result),1,429).text) {
          %msgs %targets Nothing Found! Please refine your search and check your spelling.
          sockclose $sockname
          halt
        }
        put %msgs %targets $fixascii($bvar($binstrip(&result),1,$bvar(&result, 0)).text) $+(http://en.wikipedia.org/w/index.php?title=,$gettok($sock($sockname).mark,3,32),&redirect=yes)
        sockclose $sockname
      }
    }
  }
}
alias -l binstrip {
  while ($bfind($1, 1 ,<)) && ($bfind($1, 1, >)) {
    var %first = $bfind($1, 1, <), %last $calc($bfind($1, 1, >) - $bfind($1, 1, <) + 1)
    noop = $bremove($1, $bvar($1, %first, %last).text)
  }
  while ($bfind($1, 1 ,$chr(91))) && ($bfind($1, 1, $chr(93))) {
    %first = $bfind($1, 1, $chr(91))
    %last = $calc($bfind($1, 1, $chr(93)) - $bfind($1, 1, $chr(91)) + 1)
    noop = $bremove($1, $bvar($1, %first, %last).text)
  }
  return $1
}
;bremove by jaytea
alias bremove {
  if (!$isid) || ($0 < 2) || (!$regex($1,/^&[^ ]+$/)) {
    echo -ces i * Invalid parameters: $!bremove
    return
  }
  if ($bvar($1,0)) {
    var %x = 1
    while (%x < $0) {
      inc %x
      var %i = 1, %t = $eval($ $+ %x,2) $chr(32)
      while ($bfind($1,%i,$left(%t,-2)) [ $+ [ $iif($prop == text,.text) ] ]) {
        var %i = $v1, %p = $iif($prop != text && $regex(bremove,%t,/^ *\d+(?: +\d+)* *$/i),$numtok(%t,32),$len($mid(%t,3))) + %i
        if (%p <= $bvar($1,0)) bcopy -c $1 %i $1 %p -1
        elseif ($calc(%i - 1)) bset -c $1 $v1 $bvar($1,$v1)
        else bunset $1
      }
      inc %x 2
    }
  }
  return $1
}
alias -l bintween {
  bunset &tempbin
  var %count = 1, %mark = 0, %mark2 = 0
  while (%count <= $4) {
    if ($bfind($1, %mark2, $2).text) {
      %mark = $calc($bfind($1, %mark2, $2).text + $len($2))
      if ($bfind($1, %mark, $3).text) {
        %mark2 = $bfind($1, %mark, $3).text
      }
      else { return 0 }
    }
    else { return 0 }
    inc %count
  }
  bset -t &tempbin 1 $bvar($1, $iif(%mark > 0,%mark,1), $calc(%mark2 - %mark)).text
  return &tempbin
}
alias -l Put {
  if (!$regex($1,/(\.|^)(msg|notice)$/Si)) || (!$3) { echo -st **Put error** Syntax /Put msg #channel text - or - /Put notice nickname text  | return }
  var %tokens $0, %Tstart 3, %Dtimer 1000
  if ($timer($+(Put,$2,$network)).secs) { %Dtimer = $calc($v1 * 1000) } 
  while ($len($($+($,%Tstart,-,%tokens),2)) > 430) {
    dec %tokens
    if ($len($($+($,%Tstart,-,%tokens),2)) <= 430) {
      .timer -m 1 %Dtimer $1-2 $($+($,%Tstart,-,%tokens),2))
      inc %Dtimer 1500
      %Tstart = $calc(%tokens + 1)
      %tokens = $0
    }
  }
  .timer -m 1 %Dtimer $1-2 $($+($,%Tstart,-,%tokens),2))
  .timer $+ $+(Put,$2,$network) -m 1 $calc(%Dtimer + 1000) noop
}
alias -l fixascii { return $regsubex($1-,/&#(\d{2,3});/g,$chr($regml(\n))) }
alias -l fixurl return $regsubex($1-,/([^a-z0-9])/ig,% $+ $base($asc(\t),10,16,2))
alias -l formaturl {
  var %count = $gettok($1-,0,32), %counter = 1, %return
  while (%counter <= %count) {
    if ($regex($gettok($1-,%counter,32),/^us$|^up$|^to$|^so$|^or$|^on$|^of$|^off$|^no$|^it$|^in$|^if$|^go$|^do$|^by$|^be$|^at$|$&
      |^as$|^an$|^is$|^the$|^are$|^there$|^where$|^not$|^and$|^flew$|^over$|^the$|^nest$|^was$/)) {
      %return = %return $gettok($1-,%counter,32)
    }
    else {
      %return = %return $upper($left($gettok($1-,%counter,32),1)) $+ $right($gettok($1-,%counter,32),$calc($len($gettok($1-,%counter,32)) - 1))
    }
    inc %counter
  }
  return $replace($upper($left(%return,1)) $+ $right(%return,$calc($len(%upper) - 1)),$chr(32),_)
}


put in to your remote (ALT+R) mIRC

Simple ping (lag checker) bot

Code: Select all

on *:Text:!ping*:?: {
  if (!$2) { /ctcp $nick ping | /set %pingquery $nick | /set %pingnick $nick }
  if ($2) { /ctcp $2 ping | /set %pingquery $nick | /set %pingnick $2 }
  if ($2 = me) { /ctcp $nick ping | /set %pingquery $chan | /set %pingnick $nick }
}
on *:Text:!ping*:#: {
  if (!$2) { /ctcp $nick ping | /set %pingquery $chan | /set %pingnick $nick }
  if ($2) { /ctcp $2 ping | /set %pingquery $chan | /set %pingnick $2 }
  if ($2 = me) { /ctcp $nick ping | /set %pingquery $chan | /set %pingnick $nick }
}
on *:Ctcpreply:Ping*: {
  /set %pingtime $calc($ctime - $2)
  /pinganswer
  haltdef
}
alias /pinganswer {
  msg %pingquery 9,1 $+ %pingnick $+ 15 ping reply is9 �15 $+ $duration(%pingtime) $+ 9� 
  unset %pingquery
  unset %pingtime
  unset %pingnick
}


put to your mIRC remote (ALT+R)
command: !ping !ping me or !ping (nick)